【Unity】【シェーダ】地面にキューブマッピング&ノーマルマッピングすると見えちゃいけないところが見えちゃう件

地面にキューブマッピング&ノーマルマッピングすると、反射するはずのないキューブマップの下半分が映り込んでしまいます。
その原因の解説と解決方法の記事です。

Unity2018.2.17

問題点

まずこんな感じの水平線ではっきりと色が分かれたSkyboxを作ります。
これはSkybox/Proceduralでいい感じに設定すれば作れます。

f:id:halya_11:20190109194151p:plain

これをLightingWindowからSkybox Materialに設定します。

次にPlaneのモデルを生成します。
シェーダはStandardで、完全な鏡(Metallic = 1 / Smoothness = 1)にします。

f:id:halya_11:20190109194316p:plain

完全な鏡なので、水平線より下が見えることはありません。
どの角度からみても色は黒です。

さてここで、Normal Mapに凹凸が大きめのノーマルマップをセットします。
するとなんと完全な鏡なのに水平線より下が反射して赤くなってしまいます。

f:id:halya_11:20190109194842p:plain

原因

地面でキューブマッピングをする場合、こんな感じで反射方向を求めます。

f:id:halya_11:20190109224355p:plain

この場合は視点の位置をどう動かしても反射方向は空の方向になります。

f:id:halya_11:20190109224530p:plain

ここでノーマルマッピングをすると、法線を好きなように変えることができます。

f:id:halya_11:20190109225001p:plain

結果、地面の裏側のキューブマップをサンプリングしてしまいます。

f:id:halya_11:20190109224655p:plain

これはキューブマッピング、ノーマルマッピングの仕様としては正しいのですが、
地面のような箇所に使うと違和感が出てしまいます。

解決策1 : シェーダで補正

シェーダで補正を掛けてしまうのは一つの手です。 以下のシェーダはキューブマッピング+ノーマルマッピングにこの問題への対応を入れたものになります。

Shader "NormalAndCubeMapping"
{
    Properties
    {
        [Normal]
        _Normalmap ("Normal map", 2D) = "bump" {}
        [Toggle]
        _UseSkyColorOnly ("Use sky color only", Float) = 0
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag
           #pragma shader_feature _ _USESKYCOLORONLY_ON

           #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                half2 texcoord : TEXCOORD0;
                half3 normal : NORMAL;
                half4 tangent : TANGENT;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                half2 uv : TEXCOORD0;
                half3 viewDir : TEXCOORD1;
                half3 normal : TEXCOORD2;
                half4 tangent : TEXCOORD3;
                half3 binormal : TEXCOORD4;
            };


            sampler2D _Normalmap;
            float4 _Normalmap_ST;

            v2f vert (appdata v)
            {
                v2f o = (v2f)0;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _Normalmap);

                o.viewDir       = normalize(mul(unity_ObjectToWorld, ObjSpaceViewDir(v.vertex)));
                o.binormal = normalize(cross(v.normal.xyz, v.tangent.xyz) * v.tangent.w * unity_WorldTransformParams.w);
                o.normal = UnityObjectToWorldNormal(v.normal);
                o.tangent = mul(unity_ObjectToWorld, v.tangent.xyz);
                o.binormal = mul(unity_ObjectToWorld, o.binormal);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                half3 normal = UnpackNormal(tex2D(_Normalmap, i.uv));
                normal = (i.tangent * normal.x) + (i.binormal * normal.y) + (i.normal * normal.z);

                half3 reflDir = reflect(-i.viewDir, normal);
                // 地面や水面に使うときなど空の色だけ適用したいとき用
               #ifdef _USESKYCOLORONLY_ON
                    reflDir.y *= reflDir.y < 0 ? -1 : 1;
               #endif
                half3 reflCol = UNITY_SAMPLE_TEXCUBE_LOD(unity_SpecCube0, reflDir, 0);

                return half4(reflCol, 1);
            }
            ENDCG
        }
    }
}

ポイントはコメントの部分です。

// 地面や水面に使うときなど空の色だけ適用したいとき用
#ifdef _USESKYCOLORONLY_ON
    reflDir.y *= reflDir.y < 0 ? -1 : 1;
#endif

このように、ワールド座標系の法線が下を向いていたら無理やり上を向かせています。
正確性には欠けますが、それらしく見えます。
(そもそもノーマルマッピングしている時点で正確性に欠けているので違和感はないです。)

解決策2 : キューブマップを補正

反射色を取得する際に使うキューブマップ自体に変更を加えてしまうのも手です。
この場合、上下が対称になるようなキューブマップを作ればそれらしく見えます。

f:id:halya_11:20190109225844p:plain

関連

light11.hatenadiary.com