【Unity】【シェーダ】MatCap（スフィアマッピング）を実装する

f:id:halya_11:20180614225006g:plain

MatCapとかスフィアマッピングとか呼ばれる手法の実装方法です。

MatCapとは？

ライティング済みの球体を映したテクスチャから色をいい感じにサンプリングすることで、さもライティングされているかのように見せられます。

f:id:halya_11:20180614225838p:plain

この球体が描かれたテクスチャをMatCap（Material Capture）といいます。
レンダリング結果のように見えますが、あくまで球体の描かれただけのテクスチャです。

実装の考え方

考え方はとてもシンプルです。
まず適用したいモデルとMatCapテクスチャを用意します。

f:id:halya_11:20180614230646p:plain

法線がカメラ方向（要は手前）を向いている部分はテクスチャの中心の色を取ります。
そして法線が視線と垂直になっていくにつれてテクスチャの外側をサンプリングするようにします。

f:id:halya_11:20180614224345p:plain

ちょっと雑な説明ですが、要するにこういうことです。

シェーダ

シェーダは次のように実装します。

Shader "MatCap"
{
    Properties
    {
        _MatCap ("Mat Cap", 2D) = "white" {}
    }

    Subshader
    {
        Tags { "RenderType"="Opaque" }
        
        Pass
        {
            CGPROGRAM
           #include "UnityCG.cginc"
           #pragma vertex vert
           #pragma fragment frag

            sampler2D _MatCap;
                
            struct v2f
            {
                float4 pos  : SV_POSITION;
                half2 uv    : TEXCOORD0;
            };
                
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos (v.vertex);
                
                // カメラ座標系の法線を取得
                float3 normal = UnityObjectToWorldNormal(v.normal);
                normal = mul((float3x3)UNITY_MATRIX_V, normal);

                // 法線のxyを0～1に変換する
                o.uv = normal.xy * 0.5 + 0.5;

                return o;
            }
                
            float4 frag (v2f i) : COLOR
            {
                // カメラから見た法線のxyをそのままUVとして使う
                return tex2D(_MatCap, i.uv);
            }

            ENDCG
        }
    }
}