【Unity】【シェーダ】ノーマルマッピング+キューブマッピング

ノーマルマッピングとキューブマッピングを組み合わせたシェーダの実装方法です。

シェーダ

早速ですがシェーダです。

Shader "NormalAndCubeMapping"
{
    Properties
    {
        [Normal]
        _Normalmap ("Normal map", 2D) = "bump" {}
        [Toggle]
        _UseSkyColorOnly ("Use sky color only", Float) = 0
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag
           #pragma shader_feature _ _USESKYCOLORONLY_ON

           #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex       : POSITION;
                half2 texcoord      : TEXCOORD0;
                half3 normal        : NORMAL;
                half4 tangent       : TANGENT;
            };

            struct v2f
            {
                float4 pos          : SV_POSITION;
                half2 uv            : TEXCOORD0;
                half3 viewDir       : TEXCOORD1;
                half3 normal        : TEXCOORD2;
                half4 tangent       : TEXCOORD3;
                half3 binormal      : TEXCOORD4;
            };


            sampler2D _Normalmap;
            float4 _Normalmap_ST;

            v2f vert (appdata v)
            {
                v2f o           = (v2f)0;
                o.pos           = UnityObjectToClipPos(v.vertex);
                o.uv            = TRANSFORM_TEX(v.texcoord, _Normalmap);

                // 各ベクトルをワールド空間で求める
                o.viewDir       = normalize(mul(unity_ObjectToWorld, ObjSpaceViewDir(v.vertex)));
                // binormalはtangentのwとunity_WorldTransformParams.wを掛ける（Unityの決まり）
                o.binormal      = normalize(cross(v.normal.xyz, v.tangent.xyz) * v.tangent.w * unity_WorldTransformParams.w);
                o.normal        = UnityObjectToWorldNormal(v.normal);
                o.tangent       = mul(unity_ObjectToWorld, v.tangent.xyz);
                o.binormal      = mul(unity_ObjectToWorld, o.binormal);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // ノーマルマップから法線情報を取得する
                half3 normal                    = UnpackNormal(tex2D(_Normalmap, i.uv));
                // ワールド空間に変換
                normal                          = (i.tangent * normal.x) + (i.binormal * normal.y) + (i.normal * normal.z);
                
                half3 reflDir                   = reflect(-i.viewDir, normal);
                // 地面や水面に使うときなど空の色だけ適用したいとき用
               #ifdef _USESKYCOLORONLY_ON
                    reflDir.y *= reflDir.y < 0 ? -1 : 1;
               #endif
                half3 reflCol                   = UNITY_SAMPLE_TEXCUBE_LOD(unity_SpecCube0, reflDir, 0);

                return half4(reflCol, 1);
            }
            ENDCG
        }
    }
}